Cara Menciptakan Ranking Ganda Tanpa Loncat Di Excel

Cara Membuat Ranking Ganda Tanpa Loncat Di Excel Cara Membuat Ranking Ganda Tanpa Loncat Di Excel

Rumus Ranking Ganda Tanpa Loncat - Jika Anda mengikuti tutorial kami, tentu sudah maklum bahwa fungsi Rank yang disediakan excel untuk menciptakan peringkat nilai ternyata akan menghasilkan nilai rangking yang meloncat atau melompat kalau ada nilai yang mempunyai rangking ganda/duplikat.

Coba perhatikan teladan hasil merangking dengan rumus Rank Excel berikut:

Cara Membuat Ranking Ganda Tanpa Loncat Di Excel Cara Membuat Ranking Ganda Tanpa Loncat Di Excel

Jika Anda perhatikan ternyata hasil peringkat nilai yang dihasilkan rumus Rank excel pada teladan daftar nilai tersebut menghasilkan nilai ranking 1, 3, 4, 7, 8 dan 10 dan tidak ada nilai ranking 2, 5, 6 dan 9.

Selain ada peringkat nilai yang duplikan urutan rangkingnya juga melompat dari 1 ke 3, dari 4 ke 7, dan dari 8 ke 10. Hal ini disebabkan lantaran nilai pada rangking ke 1, 4 dan 8 ada duplikatnya.

Lalu bagaimana cara menciptakan ranking di excel tanpa melewatkan urutan rangking meskipun terdapat nilai ganda atau duplikat sehinga menghasilkan nilai rangking 1, 2, 3, 4, 5 dan 6?

Untuk tutorial menciptakan rangking tanpa peringkat ganda sanggup Anda lihat pada halaman berikut: Cara mencegah peringkat ganda pada excel

Pada tutorial kali ini ada dua cara yang sanggup Anda lakukan. Pertama dengan memanfaatkan beberapa kolom dummy untuk menyusun perangkingan nilai duplikat tanpa loncat dan yang kedua dengan memakai rumus Array.

Rumus Rangking Ganda Tanpa Loncat Dengan Kolom Dummy (Bantuan)

Sebelum membaca tutorial ini, ada baiknya Anda menciptakan teladan file sendiri lalu pelan-pelan mambaca dan mempraktikkannya langsung.

Cara Membuat Ranking Ganda Tanpa Loncat Di Excel Cara Membuat Ranking Ganda Tanpa Loncat Di Excel

Langkah-Langkah yang perlu Anda lakukan untuk menciptakan rangking tanpa loncat yaitu sebagai berikut:

Buatlah nomor urut
Langkah pertama yaitu menciptakan nomor urut gres pada kolom F.

Nomor urut ini boleh Anda abaikan kalau Anda lebih menentukan untuk memakai nomor urut yang sudah ada di kolom A.
Menyusun Rangking Awal/Asli
Langkah selanjutnya yaitu memakai fungsi RANK excel pada kolom G untuk menciptakan peringkat nilai awal yang nantinya akan kita sesuaikan kembali pada kolom-kolom berikutnya.

Pada cell G2 masukkan rumus excel berikut:
```
=RANK(C2;$C$2:$C$11)
```
Copy-paste rumus pada cell G2 tersebut pada semua cell lain di bawahnya.

Mengenai cara kerja fungsi Rank ini sanggup Anda baca lebih lanjut pada halaman berikut: Fungsi RANK Excel.
Menghitung jumlah masing-masing peringkat/ranking
Pada kolom H, hitung jumlah masing-masing peringkat atau Ranking nilai sesuai nomor urutnya memakai fungsi Countif dengan memasukkan rumus excel berikut pada Cell H2 lalu copy paste ke cell lain dibawahnya.
```
=COUNTIF($G$2:$G$11;F2)
```
Dari rumus di atas akan sanggup Nada ketahui jumlah masing-masing rangking 1-10:
1. Rangking 1 ada 2
2. Rangking 2 ada 0
3. Rangking 3 ada 1
4. Rangking 4 ada 3
5. Dan seterusnya
Membuat Penyesuaian Rangking ke-1
Selanjutnya Pada kolom I kita buat dummy penyesuaian pertama, Yakni kalau Jumlah Rangking pada kolom H yaitu 0 maka tidak perlu disesuaikan, sedangkan kalau nilainya bukan 0 maka kita kurangi 1.

Masukkan rumus If excel berikut pada Cell I2, lalu copy paste ke bawahnya:
```
=IF(H2=0;0;H2-1)
```
Kenapa perlu kita kurangi 1? alasannya yang akan kita sesuaikan intinya yaitu dupliat rangkingnya saja. Jika sebuah rangking mempunyai 3 duplikat maka hanya 2 saja yang perlu kita sesuaikan.
Membuat Penyesuaian Rangking ke-2
Pada kolom J kita gunakan jumlah masing-masing rangking dan penyesuaiannya untuk menciptakan nilai penyesuaian baru. Masukkan rumus excel berikut pada cell J2.
```
=IF(AND(H2=0;I2=0);J1;SUM($I$1:I1))
```
Jika peringkat tidak ada nilainya (H2=0 dan I2=0) maka rumus akan menghasilkan nilai penyesuaian sebelummya (diatasnya), dan sebaliknya akan menghasilkan nilai penjumlahan angka penyesuaian (Kolom I) hingga baris terkait.

Perhatikan juga penggunaan tanda $ pada rumus excel tersebut.
Mengurutkan nilai Penyesuaian Masing-masing Rangking
Selanjutnya Pada kolom K, kita sejajarkan masing-masing penyesuaian rangking dengan Rangking Awal memakai fungsi INDEX. Pada K2 masukkan rumus excel berikut:
```
=INDEX($J$2:$J$11;G2)
```
Membuat Rangking Akhir
Selanjutnya tinggal kita sesuaikan Rangking Awal dengan mengurangi nilainya dengan angka penyesuaian yang telah kita buat.

Rumus pada L2 adalah:
```
=G2-K2
```
Copy paste rumus tersebut pada cell lain dibawahnya

Setelah melaksanakan rangkainya penyesuaian diatas Anda akan mendapat hasil final Rangking tanpa loncat meskipun terdapat nilai ganda atau duplikat.

Langkah terakhir yaitu mengambil Rangking yang telah diadaptasi pada kolom L ke kolom D dengan memasukkan rumus berikut pada cell D2 lalu copy paste ke cell lain dibawahnya:

=L2

Dan kesudahannya akan kita dapati rangking peringkat nilai yang tetap urut tanpa loncat.

Praktis bukan? kalau masih resah jangan ragu untuk membaca dan praktik langkah-langkah di atas 1-10x lagi. Barangkali pada urutan ke 11 Anda akan mendapat pencerahan.

Jika pada urutan ke 11 masih resah juga, sebaiknya ambil nafas dan tinggalkan dulu, lalu beralih ke cara berikutnya di bawah ini.

Rumus Rangking Ganda Tanpa Loncat Dengan Rumus Array

Untuk rumus kedua ini, kita tidak perlu menciptakan beberapa kolom dukungan dan cukup memakai 1 cell saja untuk menciptakan rangking tanpa loncat. Yakni dengan memakai Rumus Array Excel.

Cara Membuat Ranking Ganda Tanpa Loncat Di Excel Cara Membuat Ranking Ganda Tanpa Loncat Di Excel

Tulis rumus excel berikut sebagai rumus CSE (Array) pada Cell D2 tanpa tanda {...}.

=SUM(IF(C2<$C$2:$C$11;1/COUNTIF($C$2:$C$11;$C$2:$C$11)))+1

Setelah menuliskan rumus di atas akhiri dengan menekan tombol Ctrl + Shift + Enter untuk memunculkan tanda {...}

Jika Anda pernah membaca cara menghitung nilai unik pada blog tutorial excel ini, tentunya rumus di atas sudah tidak gila lagi. Sebab intinya sama.

Hanya saja dalam kasus ini nilai unik ini di beri syarat kurang dari nilai yang akan kita rangking.

Pada rumus di atas fungsi IF akan mengecek setiap nilai apakah kurang dari nilai yang akan di rangking sehingga rumus:

IF(C2<$C$2:$C$11;1/COUNTIF($C$2:$C$11;$C$2:$C$11))

Bagian logika "C2<$C$2:$C$11" Akan menghasilkan nilai:

{FALSE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE}

Untuk setiap nilai True Fungsi IF akan menghasilkan nilai rumus:

1/COUNTIF($C$2:$C$11;$C$2:$C$11)

Fungsi Countif di atas dipakai untuk menghitung jumlah masing-masing nilai sehingga di dapatkan nilai berikut:

1/{1;1;3;1;2;2;3;2;2;3}

Maksudnya nilai 60 ada 1, nilai 80 ada 1, nilai 85 ada 3, dan seterusnya untuk masing-masing nilai.

Masing-masing nilai tersebut lalu dipakai untuk membagi angka 1, sehingga didapatkan nilai:

{1/1;1/1;1/3;1/1;1/2;1/2;1/3;1/2;1/2;1/3}

Nilai diatas yang bersesuaian dengan TRUE dari logika IF akan dipakai sedangkan yang FALSE tidak dipakai atau bernilai 0:

{FALSE;1/1;1/3;1/1;1/2;1/2;1/3;1/2;1/2;1/3}

Kemudian fungsi SUM akan menjumlahkan nilai tersebut lalu ditambah angka 1, sehingga didapatkan hasil 6

SUM({1/1;1/1;1/3;1/1;1/2;1/2;1/3;1/2;1/2;1/3})+1

Nah, cukup gampang bukan?

Jangan ragu untuk meninggalkan komentar kalau masih ada yang kurang jelas.

Jika Anda mendapat manfaat dari tutorial ini, jangan lupa juga untuk klik share, semoga lebih banyak teman-teman Anda yang juga ikut mendapat manfaatkanya.

Seri tutorial menciptakan ranking di Excel lainnya: