Rumus If Bertingkat Pada Microsoft Excel Untuk Konversi Nilai Raport

Rumus IF Bertingkat - Kali ini kita akan melanjutkan sesi tutorial excel wacana Rumus IF pada microsoft excel, lebih tepatnya mengenai rumus IF bertingkat. Seperti yang sudah aku singgung sebelumnya, bahwa rumus IF sanggup digunakan hingga 64 tingkat atau cabang.

Penggunaan Fungsi IF yang semacam ini biasa disebut sebagai rumus IF bertingkat, IF berjenjang, rumus IF bercabang, rumus IF beragam atau Nested IF Function.

Rumus IF Bertingkat Untuk Konversi Rentang Nilai

Sebenarnya tidak terlalu sulit untuk memakai rumus excel IF bertingkat semacam ini.

Sebelum menciptakan rumusnya, yang perlu kita perhatikan ialah kita perlu memahami dulu kebijaksanaan kondisi/kriteria yang akan kita gunakan.

Selain itu kita juga harus menguasai atau setidaknya tahu wacana operator perbandingan pada rumus excel.

Sebagai materi pembahasan kita akan melaksanakan konversi nilai raport atau nilai siswa ibarat gambar berikut:

Kali ini kita akan melanjutkan sesi tutorial excel wacana Rumus IF Bertingkat Pada Microsoft Excel Untuk Konversi Nilai Raport

Dari tumpuan gambar di atas kita ingin nilai 0-59 akan dikonversi menjadi nilai E, 60-69 = D, 70-79 = C, 80-89 = B, 90-100 = A.

Dari kebijaksanaan nilai ini muncul pertanyaan:

Bagaimana dengan nilai di bawah 0 (minus) dan diatas 100?.

Misalkan dalam kasus ini untuk nilai minus, nilai akan kita jadikan "Nilai Minus" dan jikalau diatas 100 nilainya akan "Nilai diatas 100".

Selanjutnya, sesudah menentukan rentang nilai masing-masing kita susun rumus if bertingkatnya. Perhatikan tumpuan berikut:

Untuk rumus excel di bawah ini, nilai yang akan kita cari konversinya berada pada kolom D, mulai sel D2 hingga D6 dan D9 hingga D13. Sedangkan hasil konversi nilainya berada pada kolom E (E2:E6 dan E9:E13).

Kali ini kita akan melanjutkan sesi tutorial excel wacana Rumus IF Bertingkat Pada Microsoft Excel Untuk Konversi Nilai Raport

Pada tumpuan diatas rumus IF bertingkat yang digunakan pada cell E2 ialah sebagai berikut:

=IF(D2>=0;IF(D2<=59;"E";IF(D2<=69;"D";IF(D2<=79;"C";IF(D2<=89;"B";IF(D2<=100;"A";"Nilai diatas 100")))));"Nilai Minus")

Selanjutnya, Anda cukup copy paste rumus tersebut ke cell lain dibawahnya.

Anda bingung? Jangan tergesa-gesa. Berikutnya akan kami jelaskan bagaimana cara kerja rumus if berjenjang di atas.

Untuk kebutuhan rumus konversi angka ke aksara di excel semacam ini sesungguhnya kurang efektif. Sebab jikalau suatu dikala kita melaksanakan perubahan kriteria kita akan sedikit repot untuk mengubah rumusnya. Cara yang lebih gampang ialah memakai Fungsi Vlookup.

Untuk penjelasannya sanggup anda pelajari pada halaman berikut: Rumus Grade Excel: Cara Konversi Rentang Nilai Angka ke Huruf Pada Excel

Rumus IF Excel Sederhana

Sebelum menjelaskan cara kerja rumus if bertingkat diatas kita akan mengingat lagi wacana sintaks fungsi if :

IF(TesLogika; NilaiJikaBenar; NilaiJikaSalah)

Kemudian kita juga perlu mengingat operator perbandingan yang akan menghasilkan nilai TRUE(Nilai Benar) atau FALSE(Nilai Salah).

= Artinya "Sama dengan"
> Artinya "Lebih dari"
< Artinya "Kurang dari"
>= Artinya "Lebih dari atau Sama dengan"
<= Artinya "Kurang dari atau Sama dengan"
<> Artinya "Tidak sama dengan"

Untuk operator-operator lain sanggup anda baca pada goresan pena wacana Operator Perhitungan dalam Rumus Microsoft Excel.

Penjelasan Rumus IF Bertingkat/Bercabang

Rumus IF bertingkat ialah memakai fungsi IF excel sebagai argument dari rumus if lainnya. Pada belahan "NilaiJikaBenar" atau "NilaiJikaSalah" dan juga sanggup pada kedua belahan atau argumen fungsi IF.

Penggunaan rumus if bertingkat semacam ini sanggup bertingkat 2, bertingkat 3 dan seterusnya.

Hal ini berarti bahwa Anda sanggup memasukkan fungsi if ke dalam sebuah rumus if excel. Kemudian memasukkan fungsi IF pada rumus if yang telah dimasukkan ke dalam rumus if lain.

Sintaksisnya ibarat ini:

Rumus IF Bercabang pada NilaiJikaBenar:

=IF(TesLogika1; IF(TesLogika2; NilaiJikaBenar2; NilaiJikaSalah2); NilaiJikaSalah1)

Rumus IF Bercabang pada NilaiJikaSalah:

=IF(TesLogika1; NilaiJikaBenar1; IF(TesLogika2; NilaiJikaBenar2; NilaiJikaSalah2))

Rumus IF Bercabang pada NilaiJikaBenar dan NilaiJikaSalah:

=IF(TesLogika1; IF(TesLogika2; NilaiJikaBenar2; NilaiJikaSalah2); IF(TesLogika3; NilaiJikaBenar3; NilaiJikaSalah3))

Rumus IF bertingkat atau IF bercabang yang digunakan Pada tumpuan di atas ialah sebagai berikut:

=IF(D2>=0;IF(D2<=59;"E";IF(D2<=69;"D";IF(D2<=79;"C";IF(D2<=89;"B";IF(D2<=100;"A";"Nilai diatas 100")))));"Nilai Minus")

Dari sintaksis dasar rumus IF, kita masukkan masing-masing argumennya:

IF(TesLogika; NilaiJikaBenar; NilaiJikaSalah)

Argument TesLogika yang digunakan pada belahan pertama rumus tersebut ialah "D2>=0".
Argument NilaiJikaBenar diisi dengan rumus if lain "IF(...)".
Argument NilaiJikaSalah diisi dengan sebuah teks "Nilai Minus".

=IF(D2>=0;IF(...);"Nilai Minus")

Dari rumus excel diatas fungsi IF pertama bertingkat pada belahan TRUE(NilaiJikaBenar).

=IF(TesLogika1; IF(TesLogika2; NilaiJikaBenar2; NilaiJikaSalah2); NilaiJikaSalah1)

Maksud dari rumus diatas jikalau D2 Lebih dari atau Sama dengan 0 maka hasilkan nilai rumus IF ke-2. Jika tidak lebih dari atau sama dengan 0 (nol) maka hasilkan teks "Nilai Minus".

Misal nilai angka pada cell D2 ialah -60 maka rumus tersebut akan menghasilkan teks "Nilai Minus". Sebab -60 tidak lebih dari atau sama dengan 0.

Apabila Nilai cell D2 ialah 95 maka rumus excel tersebut akan mengerjakan fungsi IF tingkat ke-2, sebab 95 lebih dari 0.

Rumus If tingkat ke-2 ialah sebagai berikut:

IF(D2<=59;"E";IF(...))

Rumus IF tingkat ke-2 pada tumpuan di atas bertingkat pada belahan FALSE (NilaiJikaSalah).

Arti rumus if diatas jikalau D2 Kurang dari atau sama dengan 59 maka tulis "E". Jika tidak kerjakan Rumus IF ke-3.

Jika digabungkan dengan IF sebelumnya penulisannya sebagai berikut:

=IF(TesLogika1; IF(TesLogika2; NilaiJikaBenar2; IF(TesLogika3; NilaiJikaBenar3; NilaiJikaSalah3)); NilaiJikaSalah1)

Jika nilai cell D2 tidak kurang dari atau sama dengan 59 maka rumus excel akan mengerjakan fungsi IF ke-3 sebagai berikut :

IF(D2<=69;"D";IF(...))

Rumus IF ke-3 ini bertingkat pada belahan "NilaiJikaSalah" ibarat sebelumnya.

Jika digabungkan dengan fungsi IF sebelumnya penulisannya sebagai berikut:

=IF(TesLogika1; IF(TesLogika2; NilaiJikaBenar2; IF(TesLogika3; NilaiJikaBenar3; IF(TesLogika4; NilaiJikaBenar4; NilaiJikaSalah4))); NilaiJikaSalah1)

Dan seterusnya. Sampai disini aku yakin anda sudah sanggup memahami bagaimana cara kerja fungsi IF berjenjang ini.

Selain dengan rumus diatas fungsi IF bertingkat/bercabang dalam kasus ini sanggup juga anda tulis ibarat berikut :

=IF(D2>=0;IF(D2<60;"E";IF(D2<70;"D";IF(D2<80;"C";IF(D2<90;"B";IF(D2<=100;"A";"Nilai diatas 100")))));"Nilai Minus")

Yang membedakan dengan fungsi sebelumnya hanyalah operator perbandingannya saja. Kaprikornus suka-suka anda lebih menentukan yang mana. Tinggal bagaimana kreatifitas kita saja dalam menyusun rumus excel yang lebih efisien.

Download Contoh File Rumus IF Bertingkat

File untuk materi rumus excel ini sanggup anda unduh dibawah ini:

Dropbox
GDrive

*Jika link mati / tidak sanggup diakses silahkan lapor via kontak yang tersedia

Jika masih ada yang perlu ditanyakan silahkan sampaikan pada kolom komentar yang tersedia.

Selain memakai rumus excel IF bercabang ganda atau majemuk, Fungsi IF pada excel juga biasa digabungkan dengan kebijaksanaan AND dan atau fungsi OR excel. Tutorial cara menggabungkannya sanggup anda baca pada bagian: Rumus Excel Gabungan Fungsi IF-AND-OR

Untuk tumpuan penggunaan fungsi IF dan VLookup sanggup anda baca pada laman berikut: Gabungan Penggunaan Rumus Excel IF dan VLookup

Adapun adonan fungsi IF dengan fungsi Min atau Max (MAX-IF, MIN-IF) sanggup anda baca pada tutorial excel berikut: Rumus Excel Max-if dan Min-IF, Mencari nilai tertinggi/terendah berkriteria