Rumus Excel Menghitung Jumlah Kata Atau Teks

Rumus Menghitung Jumlah Kata - Untuk mengetahui jumlah karakter atau aksara pada sebuah sel excel, kita sanggup memakai fungsi Len yang sudah di bahas pada tutorial excel yang lalu.

Lalu bagaimana cara menghitung jumlah kata pada sebuah sel atau range excel?

Meskipun excel tidak menyediakan fungsi khusus untuk menghitung kata (count word), bukan berarti excel tidak sanggup melaksanakan hal ini.

Kelas excel kali ini akan membahas rumus-rumus excel yang sanggup kita gunakan untuk memecahkan kasus ini.

Untuk lebih jelasnya mari kita bahas dilema ini satu persatu.

Istilah kata yang dimaksud pada pembahasan ini ialah sekumpulan aksara atau karakter teks yang dipisahkan oleh spasi.

Menghitung Jumlah Total Kata Sebuah Cell

Untuk menghitung jumlah kata dalam kalimat sebuah sel pada microsoft excel kita sanggup memakai rumus excel berikut:

=LEN(Kalimat)-LEN(SUBSTITUTE(Kalimat;" ";""))+1

Kalimat pada rumus diatas merupakan teks atau referensi sel yang akan kita hitung jumlah total katanya. Contoh penerapannya ialah sebagai berikut:

Rumus Excel Menghitung Jumlah Kata atau Teks Rumus Excel Menghitung Jumlah Kata atau Teks

Pada sel B2 di atas rumus yang dipakai adalah:

=LEN(A2)-LEN(SUBSTITUTE(A2;" ";""))+1

LEN(A2) dimaksudkan untuk menghitung jumlah keseluruhan karakter pada sel A2. Sedangkan LEN(SUBSTITUTE(A2;" ";"")) dipakai untuk menghitung jumlah karakter teks tersebut tanpa menghitung spasi.

Agar sanggup menghitung jumlah karakter tanpa spasi maka spasi perlu kita hilangkan terlebih dahulu yakni dengan memakai fungsi SUBSTITUTE menyerupai di atas.

Jika pada kalimat yang akan kita hitung jumlah total kata-nya terdapat spasi ganda rumus di atas akan menghasilkan nilai yang tidak tepat. untuk itu spasi ganda harus kita hilangkan terlebih dahulu dari teks ini. Caranya ialah dengan memakai fungsi TRIM, sehingga rumus excelnya akan menjadi sepeti di bawah ini:

=LEN(TRIM(A2))-LEN(SUBSTITUTE(A2;" ";""))+1

Tentang cara menghilangkan spasi ganda ini ada pembahasan tersendiri yang sanggup anda temukan pada tutorial berikut:

Cara Menghapus Spasi Ganda atau Berlebih di Excel

Tanpa menghitung jumlah kata per sel, bisakah kita menghitung jumlah keseluruhan kata pada sebuah range excel? mari lanjut ke pembahasan berikutnya.

Menghitung Jumlah Total Kata Pada Sebuah Range

Jika pada rumus excel sebelumnya hanya menghitung kata dari sebuah sel, maka bagaimana cara untuk menghitung jumlah keseluruhan kata dari sebuah range?

Selain menghitung sel satu persatu kemudian menjumlahkan jadinya contohnya dengan fungsi SUM untuk mengetahui jumlah keseluruhan kata pada sel, kita sanggup juga menghitung total kata pada sebuah range secara pribadi dengan memakai sebuah array formula.

Apa itu array formula sudah kita bahas sebelumnya. Jika belum membacanya silahkan menuju laman berikut terlebih dahulu:

Array formula pada microsoft excel

Rumus array yang dimaksud ialah sebagai berikut:

=SUM(LEN(RangeKalimat)-LEN(SUBSTITUTE(RangeKalimat;" ";""))+1)

Setelah menuliskan rumus di atas akhiri dengan menekan tombol Ctrl + Shift + Enter secara bersama-sama.

Perhatikan tumpuan berikut:

Rumus Excel Menghitung Jumlah Kata atau Teks Rumus Excel Menghitung Jumlah Kata atau Teks

Rumus excel pada sel B8 di atas adalah:

{=SUM(LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4;" ";""))+1)}

Tanda {...} tidak kita tulis manual, melainkan otomatis muncul sebagai penunjuk bahwa rumus tersebut merupakan rumus Array yang kita inputkan dengan cara menekan CSE Ctrl + Shift + Enter secara bersama-sama.

Selain memakai rumus array menyerupai di atas kita juga sanggup memakai formula excel biasa yakni dengan memanfaatkan fungsi Sumproduct berikut:

=SUMPRODUCT(LEN(RangeKalimat)-LEN(SUBSTITUTE(RangeKalimat;" ";""))+1)

Jika diterapkan pada tumpuan di atas rumus excelnya akan menjadi menyerupai pada sel B9 tumpuan di atas:

=SUMPRODUCT(LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4;" ";""))+1)

Selain memakai rumus pada bab sebelumnya, untuk sel tunggal sanggup juga kita hitung jumlah katanya dengan kedua rumus yang dijelaskan pada bab ini.

Setelah mempelajari kedua rumus di atas biasanya akan muncul pertanyaan "Bagaimana jikalau kita hanya menghendaki menghitung jumlah kata tertentu saja?"

Menghitung Jumlah Kata Tertentu Pada Sebuah Cell Excel

Selain menghitung jumlah total keseluruhan kata dalam sebuah kalimat di excel, kita juga sanggup menghitung jumlah kata atau teks tertentu saja.

Caranya ialah dengan memakai rumus excel berikut:

=SUM(LEN(AlamatSel)-LEN(SUBSTITUTE(AlamatSel;"TeksDihitung","")))/LEN("TeksDihitung")

Misalnya untuk menghitung jumlah kata "excel" pada sel A2 rumus yang dipakai adalah:

=SUM(LEN(A2)-LEN(SUBSTITUTE(A2;"excel";"")))/LEN(A5)

Perlu diketahui bahwa fungsi Subtitute bersifat case sensitive(huruf besar dan kecil dianggap berbeda), sehingga kata "excel" dan "Excel" akan dianggap berbeda.

Jika anda ingin menghitung jumlah kata tanpa membedakan besar kecilnya aksara maka teks dalam sel yang akan kita hitung perlu kita rubah ke aksara besar semua atau menjadi aksara kecil semua dengan fungsi UPPER atau LOWER.

Rumus di atas jikalau gunakan untuk menghitung jumlah kata tertentu tanpa membedakan besar kecilnya aksara menjadi menyerupai berikut:

Rumus Excel Menghitung Jumlah Kata atau Teks Rumus Excel Menghitung Jumlah Kata atau Teks

=SUM(LEN(A2)-LEN(SUBSTITUTE(UPPER(A2);UPPER(A5);"")))/LEN(A5)

atau

=SUM(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2);LOWER(A5);"")))/LEN(A5)

Bagaimana untuk menghitung teks tertentu pada sebuah range?

Menghitung Jumlah Kata Tertentu Pada Sebuah Range Excel

Selain dipakai untuk menghitung jumlah teks atau kata tertentu pada sebuah sel rumus diatas sanggup juga diterapkan untuk sebuah range. Hanya saja rumus ini diperlakukan sebagai rumus array yang harus di akhiri dengan Ctrl + Shift + Enter.

{=SUM(LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4;"excel";"")))/LEN("excel")}

Jika tidak menghendaki memakai array formula, gunakan fungsi Sumproduct untuk menggantikan fungsi SUM pada rumus di atas.

=SUMPRODUCT(LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4;"excel";"")))/LEN("excel")

Seperti sebelumnya jikalau ingin mengabaikan aksara besar dan kecil maka gunakan fungsi LOWER atau UPPER pada kedua rumus di atas.

{=SUM(LEN(A2:A4)-LEN(SUBSTITUTE(LOWER(A2:A4);LOWER("Excel");"")))/LEN("Excel")}

=SUMPRODUCT(LEN(A2:A4)-LEN(SUBSTITUTE(LOWER(A2:A4);LOWER("Excel");"")))/LEN("Excel")

Rumus-rumus di atas dipakai untuk menghitung teks/kata tertentu pada sel dan range excel. Lalu bagaimana cara menghitung banyaknya sel yang mengandung teks tertentu?

Pertanyaan ini akan kita jawab pada tutorial excel berikutnya.

Cara Menghitung Jumlah Data Yang Mengandung Teks Tertentu Pada Microsoft Excel

Silahkan subscribe atau berlangganan artikel tutorial excel semoga segera mendapat pemberitahuan setiap ada artikel gres dari blog ini. Jangan lupa juga Join akun media sosial resmi kami.