5 Cara Vlookup Excel Ke Arah Kiri Dengan Rumus Excel

Salah satu kekurangan pencarian atau lookup data dengan fungsi VLOOKUP yaitu tidak sanggup mencari atau mengambil data di sebelah kiri kolom pencarian. VLOOKUP tidak sanggup menoleh ke kiri alasannya yaitu hanya sanggup mencari data pada kolom paling kiri dari tabel pencarian yang diberikan.

Dalam kasus-kasus tertentu kita membutuhkan cara untuk sanggup mengambil data yang sebaris pada kolom pencarian. Namun, data tersebut ada disebelah kiri kolom pencarian. Misalnya menyerupai contoh masalah di bawah ini.

Cara Vlookup Data Ke Arah Kiri Dengan Rumus Excel 5 Cara Vlookup Excel Ke Arah Kiri Dengan Rumus Excel

Dari gambar tersebut jikalau diketahui nama depan maka kita sanggup menggunakan rumus VLOOKUP biasa untuk mendapat Nama belakang, Nomor ID atau Kota yang sebaris dengan nama tersebut. Namun, lantaran yang diketahui atau diinput yaitu nomor ID dan kita ingin mendapat nilai sel yang sebaris pada kolom nama dari nomor ID tersebut misalnya, nama depan dan belakang, maka kita tidak sanggup menggunakan rumus VLOOKUP dengan cara biasa.

Adakah rumus yang digunakan apabila hendak membaca tabel dari kanan ke kiri?

Ada beberapa adonan fungsi excel yang sanggup kita rangkai untuk menjadi sebuah rumus excel sebagai solusi masalah pencarian data ke arah kiri atau VLOOKUP yang sanggup menoleh ke kiri ini.

**File contoh pembahasan sanggup anda download pada cuilan selesai pembahasan

1. Rumus VLOOKUP Ke arah Kiri Dengan Fungsi INDIRECT, ADDRESS, MATCH, ROW Dan COLUMN

Kita sanggup menggunakan kombinasi fungsi INDIRECT, ADDRESS, MATCH , ROW dan COLUMN untuk menggantikan fungsi Vlookup ke arah kiri. Sintaks rumus excel yang digunakan dalam rumus ini adalah:

=INDIRECT(ADDRESS(MATCH(DiCari;KolomPencarian;0)+ROW(SelPertamaKolomPencarian)-1;COLUMN(KolomPengambilan)))

Perhatikan conroh gambar berikut:

Cara Vlookup Data Ke Arah Kiri Dengan Rumus Excel 5 Cara Vlookup Excel Ke Arah Kiri Dengan Rumus Excel

Pada gambar diatas rumus yang digunakan untuk mendapat Nama depan adalah:

=INDIRECT(ADDRESS(MATCH(H2;D2:D10;0)+ROW(D2)-1;COLUMN(B2:B10)))

Sedangkan untuk mendapat nama belakang rumus yang digunakan adalah:

=INDIRECT(ADDRESS(MATCH(H2;D2:D10;0)+ROW(D2)-1;COLUMN(C2:C10)))

Sel H2 merupakan sel yang akan kita cari posisinya pada Kolom Atau Range D2:D10. Jika sudah ketemu posisinya maka kita akan ambil data pada range B2:B10 yang sebaris dengan hasil pencarian tersebut.

Cara kerja rumus diatas yaitu sebagai berikut:

Fungsi MATCH akan mencari posisi nilai yag dicari pada kolom pencarian. Karena sel pertama bernilai 1 sedangkan yang kita harapkan yaitu posisi baris pada data maka hasil match ini perlu ditambah dengan jumlah baris diatas kolom pencarian. jumlah baris tersebut sanggup didapat dengan menggunakan rumus excel:

ROW(D2)-1

Rumus diatas sanggup juga kita ganti eksklusif dengan jumlah baris diatas kolom pencarian, Jika mengacu pada contoh maka jumlah barisnya yaitu 1.

Hasil dari rumus MATCH digunakan untuk mengisi argumen posisi baris pada fungsi ADDRESS. Sedangkan rumus COLUMN dugunakan untuk mengisi posisi kolom pada fungsi ADDRESS.

Alamat sel yang dihasilkan oleh fungsi ADDRESS tadi diambil datanya menggunakan fungsi INDIRECT.

Untuk klarifikasi lebih lanjut perihal fungsi-fungsi excel diatas sanggup anda pelajari pada cuilan lain weblog ini.

2. Rumus VLOOKUP Ke Arah Kiri Dengan Fungsi OFFSET-MATCH

Cara kedua untuk melaksanakan Vlookup data ke arah kiri yaitu dengan menggunakan adonan fungsi OFFSET dan MATCH Excel.

Sintaks yang dipakai:

=OFFSET(HeaderKolomPengambilan;MATCH(Dicari;KolomPencarian;0);0)

Pada gambar diatas rumus excel yang digunakan untuk mencari nama depan adalah:

=OFFSET(B1;MATCH(H2;D2:D10;0);0)

Sedangkan untuk nama belakang adalah:

=OFFSET(C1;MATCH(H2;D2:D10;0);0)

Yang perlu dicatat jikalau menggunakan formula excel ini untuk melakkan vlookup yang mnoleh ke kiri, bahwa baris sel contoh OFFSET harus diatas sel pertama kolom pencarian.

Pada contoh diatas sel pertama kolom pencarian yaitu H2. Maka contoh offset menggunakan sel pada baris 1. Sedangkan kolomnya menyesuiakan kolom mana yang akan diambil.

3. Rumus VLOOKUP Ke Arah Kiri Dengan Fungsi INDEX-MATCH

Cara ketiga ini tolong-menolong sudah aku ulas pada tutorial excel sebelumnya. Cara ini merupakan cara yg sering aku temukan digunakan oleh kebanyakan pengguna excel, yakni mennggunakan fungsi Index dan match pada excel.

Untuk menggantikan vlookup yang tidak sanggup menoleh ke kiri dengan cara rumus excel ini gunakan sintak berikut:

=INDEX(KolomPengambilan;MATCH(Dicari;KolomPencarian;0))

Perhatikan contoh gambar berikut ini:

Cara Vlookup Data Ke Arah Kiri Dengan Rumus Excel 5 Cara Vlookup Excel Ke Arah Kiri Dengan Rumus Excel

Formula Excel untuk mendapat nama depan adalah:

=INDEX(B2:B10;MATCH(H2;D2:D10;0))

Sedangkan untuk mendapat nama belakang:

=INDEX(C2:C10;MATCH(H2;D2:D10;0))

Cara ini relatif lebih gampang jikalau dibandingkan dengan cara-cara sebelumnya. Sebab kita tidak butuh memperhitungakn posisi baris dimana tabel data berada. Selain itu kombinasi rumus excel INDEX-MATCH ini juga lebih mudah cara pemakaiannya.

Lebih dalam perihal adonan rumus INDEX-MATCH sanggup anda pelajari melalui link dibawah berikut: Rumus Excel INDEX MATCH : Rumus Alternatif Pengganti VLOOKUP

4. Rumus VLOOKUP Ke Arah Kiri Dengan Fungsi HLOOKUP-MATCH

Cara lain untuk melaksanakan Vlookup Data yang sanggup menoleh ke kiri yaitu dengan menggunakn adonan fungsi HLOOKUP dan MATCH. Sintaks nya adlah sebagai berikut:

=HLOOKUP(HeaderKolomPengambilan;TabelData;MATCH(DiCari;KolomPencarian;0);FALSE)

Jika sudah terbiasa menggunakan fungsi Hlookup semestinya memahami rumus ini tidaklah sulit. Pada contoh diatas rumus yang digunakan untuk mendapat nama depan dengan cara ini adalah:

=HLOOKUP("Nama Depan";A1:E10;MATCH(H2;D1:D10;0);FALSE)

Sedangkan untuk nama belakang:

=HLOOKUP("Nama Belakang";A1:E10;MATCH(H2;D1:D10;0);FALSE)

Kunci rumus diatas yaitu pada fungsi MATCH yang digunakan untuk mengisi nomor kolom pada argumen fungsi HLOOKUP. Jika diharapkan silahkan baca klarifikasi lebih detail perihal fungsi HLOOKUP pada link berikut: Fungsi dan Rumus HLOOKUP

5. Rumus VLOOKUP Ke Arah Kiri Dengan Fungsi VLOOKUP-CHOOSE

Cara kelima yaitu menggunakan fungsi Vlookup Excel. Sebenarnya VLOOKUP sendiri juga sanggup menoleh ke kiri lho... Nah caranya yaitu dengan menggabungkannya dengan fungsi CHOOSE.

Cara penulisan rumus excel vlookup-Choose begini:

=VLOOKUP(Dicari;CHOOSE({1\2};KolomPencarian;KolomPengambilan);2;FALSE)

Jadi, pada rumus diatas fungsi CHOOSE digunakan untuk membalik posisi kolom pencarian supaya berada di sebelah kiri pengambilan. Dengan rumus ini, tolong-menolong VLOOKUP tetap mengambil data di sebelah kanan kolom pencarian.

Cara Vlookup Data Ke Arah Kiri Dengan Rumus Excel 5 Cara Vlookup Excel Ke Arah Kiri Dengan Rumus Excel

Untuk mendapat nama depan dengan cara Vlookup-Choose pada gambar diatas yaitu dengan menggunakan rumus excel:

=VLOOKUP(H2;CHOOSE({1\2};D2:D10;B2:B10);2;FALSE)

Sedangkan untuk nama belakang:

=VLOOKUP(H2;CHOOSE({1\2};D2:D10;C2:C10);2;FALSE)

Jika anda menggunakan regional setting english atau sejenisnya rumus yang digunakan tidak menyerupai diatas. Sebab pada Setting english pemisah argumen dan pemisah kolom array menggunakan koma(,) bukan slash (\) menyerupai rumus diatas.

Untuk yang menggunakan region english atau sejensinya untuk mendapat nama depan pada contoh diatas gunakan rumus ini:

=VLOOKUP(H2,CHOOSE({1,2},D2:D10,B2:B10),2,FALSE)

dan rumus excel berikut untuk nama belakangnya:

=VLOOKUP(H2,CHOOSE({1,2},D2:D10,C2:C10),2,FALSE)

Demikian 5 cara untuk melaksanakan vlookup ke arah kiri atau vlookup yang sanggup menoleh ke kiri dengan banyak sekali kombinasi fungsi-fungsi excel. Formula excel mana yang anda pilih?

File contoh untuk pembahasan kali ini tersedia pada link di bawah ini :

Dropbox
GDrive

*Jika link mati / tidak sanggup diakses silahkan lapor via kontak yang tersedia

Jika anda menemukan cara lain jangan lupa untuk membuatkan di kolom komentar.

Berikut beberapa tutorial excel lain perihal Rumus VLookup yang sanggup anda pelajari: