Cara Memisahkan Nama Depan, Tengah Dan Belakang Di Excel

Kali ini kita akan berguru memakai rumus excel untuk memisahkan kata/kalimat teks atau lebih tepatnya memisahkan nama depan, tengah dan belakang pada sebuah teks nama lengkap di Microsoft Excel.

• Memisahkan Nama Lengkap Dengan Fitur "Text To Columns" Excel
• Mengambil Nama Depan
• Mengambil Nama Belakang
1. Nama Belakang Adalah Kata Setelah Spasi Pertama Dan Kosong Jika Nama Lengkap Hanya Terdiri Dari Satu Kosa Kata
2. Nama Belakang Adalah Kata Setelah Spasi Pertama Dan Jika Nama Lengkap Hanya Terdiri Dari Satu Kosa Kata Maka Nama Belakang Sama Dengan Nama Depan
3. Nama Belakang Hanya Kata Setelah Spasi Terakhir
• Mengambil Nama Tengah

Untuk memisahkan kata yang dipisahkan oleh spasi menjadi beberapa kolom sesungguhnya relatif mudah. Excel sudah menyediakan sebuah hidangan khusus untuk melaksanakan hal ini, yakni dengan menggukan hidangan "Text to Columns" yang sudah dijelaskan pada halaman lain.

Fitur "Text to Columns" sanggup juga kita manfaatkan untuk memisahkan nama depan, tengah dan belakang secara manual. Namun terkadang kita membutuhkan rumus-rumus excel khusus untuk memenuhi kebutuhan pemisahan nama yang tidak sanggup kita lakukan dengan fitur "Text to Columns".

Sebelum membahas pemisahan nama dengan rumus excel akan saya bahas sedikit wacana penggunaan fitur "Text to Column" ini, gres setelahnya akan saya bahas wacana cara memisahkan nama depan, tengah dan belakang memakai rumus-rumus microsoft excel.

*File embel-embel rumus excel wacana memisahkan nama ini sanggup anda download pada potongan simpulan artikel ini.

A. Memisahkan Nama Dengan Fitur Text To Columns

Ikuti langkah-langkah berikut untuk memakai fitur Text to Column untuk memisahkan nama menurut spasi.

1. Tandai atau seleksi nama-nama yang akan dipisah-pisahkan
   
   
   
2. Pilih hidangan TABData--Text to Columns
   
   
   
3. Pada option box pilih Delimited lalu klik Next
   
   
   
4. Pada options delimiter pastikan Space tercentang lalu klik Next
   
   
   
5. Beikutnya muncul option data format untuk masing-masing kolom. Jika perlu tentukan format pada masing-masing kolom. Atau biarkan saja.
6. Klik Finish. Selesai
   
   

Setelah melaksanakan langkah-langkah diatas, teks sudah terpisah sesuai spasi pada teks sebelumnya.

Hasil pemisahan teks diatas ialah sebagai berikut :



Jika anda mempraktekkanya tentu anda tahu bahwa dengan memakai fitur text to columns, teks awal yang dipisah tersebut menjadi berubah, yakni terpisah-pisah menjadi beberapa kolom. Dalam kasus tertentu, tentunya bukan yang ibarat ini yang kita harapkan dalam pemisahan nama. Untuk itu simak cara pemishan nama depan, tengah dan nama belakang berikutnya.

BACA PELAN-PELAN CARA PEMISAHAN NAMA DENGAN RUMUS EXCEL DIBAWAH INI. JANGAN TERGESA-GESA AGAR TIDAK TERSESAT :)

B. Rumus Mengambil Nama Depan

Biasanya nama depan ialah nama sebelum spasi pertama. Untuk mengambil nama depan maka sanggup kita lakukan dengan menggunakan fungsi LEFT dengan menggunakan fungsi FIND untuk mencari posisi spasi (" ") pertama dari kiri. Hasil pencarian posisi ini dipakai untuk mengisi jumlah huruf yang diambil dengan fungsi LEFT.

Rumus Excelnya ialah sebagai berikut:

=LEFT(Nama_Lengkap;FIND(" ";Nama_Lengkap;1)-1)

Selain memakai fungsi FIND untuk mencari posisi spasi pertama, anda juga sanggup memakai fungsi SEARCH. Untuk lebih jelasnya perhatikan pola gambar berikut:



Kenapa jumlah huruf atau posisi spasi harus minus satu (-1)?

Rumus Excel FIND(" ";Nama_Lengkap;1) dipakai untuk mencari posisi spasi pertama, sehingga bila tidak kita kurangi satu maka nama depan yang dihasilkan akan mengandung spasi yang secara kasat mata tidak terlihat di simpulan teks nama depan tersebut.

Cara lain semoga spasi di simpulan teks nama depan tidak ikut tertulis ialah dengan menggunakan fungsi TRIM, sehingga rumus excelnya menjadi:

=TRIM(LEFT(Nama_Lengkap;FIND(" ";Nama_Lengkap;1)))

Contoh penggunaannya ibarat gambar berikut:



Lebih sempurna memakai FIND atau SEARCH? baca klarifikasi kedua fungsi ini pada artikel berikut: "Beda Fungsi FIND dan SEARCH".

Loh... kog alhasil ada yang mengandung pesan error #VALUE ?

Seperti yang terlihat dalam kedua pola diatas untuk nama yang hanya terdiri dari satu kosa kata atau tidak mengandung spasi hasil pengambilan nama depan ialah sebuah pesan kesalahan/error (#VALUE). Hal ini disebabkan rumus yang kita jalankan tidak sanggup menemukan spasi (" ") pada nama lengkap.

Untuk mengatasi ini gunakan fungsi IFERROR. sehingga rumus excelnya akan menjadi:

=IFERROR(LEFT(Nama_Lengkap;FIND(" "; Nama_Lengkap;1)-1); Nama_Lengkap)

atau bila memakai fungsi TRIM:

=IFERROR(TRIM(LEFT(Nama_Lengkap;FIND(" "; Nama_Lengkap;1))); Nama_Lengkap)

Setalah memakai rumus excel tersebut alhasil akan ibarat gambar di bawah ini:



Sebenarnya masih ada sedikit pertanyaan wacana nama depan ini. Bagaimana bila nama depan mengandung gelar? misal : Dr. Setya Budi Pranomo. Jika memakai rumus-rumus excel diatas tentunya hasil nama depan ialah "Dr." padahal yang kita harapkan nama depan ialah "Dr. Setya " atau "Setya" saja.

Untuk kasus nama dengan gelar akan kita bahas lain waktu. Sekarang kita lanjut dulu cara mendapat nama belakang.

C. Rumus Mengambil Nama Belakang

Cara mengambil nama tengah ini sedikit rumit jadi harap sabar membaca step by stepnya.

Sebelum menetapkan rumus excel mana yang harus digunakan, kita tentukan dulu kriteria nama belakang itu ibarat apa bila nama yang akan kita pisahkan tidak terdiri dua kosa kata.

Maksud saya begini, bila namanya hanya terdiri 1 kata misal "Abdurrahman", maka nama belakangnya kosong atau Abdurrahman (sama dengan nama depannya). Jika namanya terdiri dari 3 kosa kata misal "Bhinneka Tunggal Ika" maka nama belakangnya "Ika" saja atau "Tunggal Ika".

Pilihan diatas tentunya terserah mau anda ibarat apa. Biasanya pemisahan nama belakang ini juga dipengaruhi apakah selain memisahkan nama depan dan belakang anda juga perlu memisahkan nama tengah atau cukup nama depan dan belakang saja.

Jika sudah mengambil keputusan model nama belakang ibarat apa yang anda gunakan lanjutkan membaca cara mengambil nama belakang di excel berikut ini.

1. Nama Belakang Adalah Kata sehabis Spasi Pertama dan Kosong Jika Hanya Terdiri Dari Satu Kosa Kata

Untuk model pertama ini, nama belakang ialah selain nama depan. Jika hanya ada nama depan (nama depan hanya terdiri satu kosa kata) maka nama belakangnya kosong. Rumus excel yang kita gunakan untuk model nama belakang ini adalah:

=IFERROR(RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND(" ";Nama_Lengkap;1));"")

Rumus diatas mengambil huruf Nama_Lengkap dari sebelah kanan. Kebalikan dari cara mengambil nama depan sebelumnya.

RIGHT(Nama_Lengkap; ...;1)

Jumlah huruf yang diambil ialah selisih antara jumlah huruf Nama_Lengkap dengan posisi spasi pertama.

LEN(Nama_Lengkap)-FIND(" ";Nama_Lengkap;1)

Jika tidak ditemukan spasi, maka alhasil kosong ("")

IFERROR( ... ;"")

Contoh mengambil nama belakang dengan rumus ini ialah :



Selain memakai fungsi RIGHT anda juga sanggup memakai fungsi MID untuk memisahkan nama belakang model ini. Rumusnya adalah:

=MID(Nama_Lengkap;FIND(" ";Nama_Lengkap;1)+1;LEN(Nama_Lengkap)-FIND(" ";Nama_Lengkap;1))

Agar sanggup diterapkan juga untuk nama yang hanya terdiri dari satu kosa kata tambahkan IFERROR.

=IFERROR(MID(Nama_Lengkap;FIND(" ";Nama_Lengkap;1)+1;LEN(Nama_Lengkap)-FIND(" ";Nama_Lengkap;1));"")

Contoh memisahkan nama belakang dengan rumus ini sebagai berikut:

2. Nama Belakang Adalah Kata sehabis Spasi Pertama dan Jika Hanya Terdiri Dari Satu Kosa Kata Maka Nama Belakang Sama dengan Nama Depan

Untuk model kedua, nama belakang ialah selain nama depan. Jika hanya ada nama depan (nama depan hanya terdiri satu kosa kata) maka nama belakangnya sama dengan nama depan. Rumus excel yang kita gunakan untuk model ini ibarat dengan model pertama hanya beda di potongan terakhir:

=IFERROR(RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND(" ";Nama_Lengkap;1));Nama_Lengkap)

Contoh penerapannya sebagai berikut:



Bisa memakai fungsi MID ibarat model pertama rumus excelnya adalah:

=IFERROR(MID(Nama_Lengkap;FIND(" ";Nama_Lengkap;1)+1;LEN(Nama_Lengkap)-FIND(" ";Nama_Lengkap;1));Nama_Lengkap)

Contoh penggunaannya:

Perhatikan hasil untuk nama Abdurrahman untuk membedakan hasil rumus model kedua ini dengan rumus model pertama sebelumnya.

3. Nama Belakang Hanya Kata Setelah Spasi Terakhir

Model ketiga ini biasanya dipakai bila selain nama depan dan belakang anda juga perlu memisahkan nama tengah.

Untuk Jenis nama belakang ini, misal nama lengkapnya ialah "Bhinneka Tunggal Ika" maka nama belakangnya ialah "Ika". Rumus Excelnya sebagai berikut:

=RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND("*";SUBSTITUTE(Nama_Lengkap;" ";"*";LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")))))

Agar tidak menghasilkan nilai error #VALUE bila ada nama yang hanya terdiri dari satu kosa kata tambahkan IFERROR ibarat model-model sebelumnya, Sehingga rumus excelnya menjadi:

=IFERROR(RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND("*";SUBSTITUTE(Nama_Lengkap;" ";"*";LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")))));"")

Contoh penggunaan rumus ini sebagai berikut:



Untuk nama belakang model ini rumusnya memang sedikit rumit, alasannya ialah nama lengkap seseorang ketika ini kebanyakan terdiri lebih dari dua suku kata belum lagi kalau ada titlenya berderet-deret.

Cara kerja rumus diatas bila dijabarkan lebih lanjut ialah sebagai berikut:

1. Mengambil beberapa huruf dari kanan:
   

   RIGHT(Nama_Lengkap;Banyak_Karakter)

2. Banyak Karakter pada langkah nomor 1 ialah jumlah huruf Nama_Lengkap dikurangi posisi tanda bintang (*).
3. Untuk mencari banyak huruf Nama_Lengkap ialah dengan menggunakan fungsi LEN
   

   LEN(Nama_Lengkap)

4. Sebelum melaksanakan pencarian tanda bintang, ganti spasi terakhir Nama_Lengkap dengan tanda bintang (*). Untuk melaksanakan hal ini kita menggunakan fungsi SUBSTITUTE
   

   SUBSTITUTE(Nama_Lengkap;" ";"*";Posisi_Spasi_Terakhir))

5. Untuk mengetahui posisi spasi terakhir kurangi jumlah huruf Nama_Lengkap dengan Nama_Lengkap tanpa spasi
   

   LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")

6. Langkah 4 dan 5 bila digabung menjadi:
   

   SUBSTITUTE(Nama_Lengkap;" ";"*";LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")))

7. 7. Untuk mencari posisi tanda bintang (*)
   

   FIND("*";Rumus_Nomor_6)

Garis besar langkah-langkah diatas ialah ganti spasi terakhir dengan tanda bintang dan lakukan pengambilan sejumlah huruf sehabis tanda bintang tersebut.

Rumus diatas menghasilkan teks kosong ("") bila nama hanya terdiri dari satu kosa kata saja. Jika anda menghendaki nama belakang sama dengan nama depan untuk Nama_lengkap yang terdiri dari satu kosa kata, ganti potongan terakhir rumus diatas dengan referensi nama_lengkap, sehingga rumus excelnya menjadi:

=IFERROR(RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND("*";SUBSTITUTE(Nama_Lengkap;" ";"*";LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")))));Nama_Lengkap)

Perhatikan nama Abdurrahman pada pola berikut dan bandingkan dengan hasil sebelumnya:



Masih punya dilema dengan nama cara memisahkan nama belakang? sampaikan di kolom komentar. Sekarang kita lanjut dulu wacana cara memisahkan atau mengambil nama tengah.

C. Rumus Mengambil Nama Tengah

Setelah memahami cara memisahkan nama depan dan nama belakang dengan rumus-rumus excel diatas berikutnya kita akan berguru tenatng cara memisahkan nama tengah.

Karena nama tengah pastinya ada di potongan tengah sebuah nama, fungsi utama yang kita gunakan ialah fungsi MID. Yakni mengambil beberapa huruf teks dimulai dari posisi spasi pertama sebanyak jumlah antara posisi spasi pertama dan jumlah huruf sehabis spasi terakhir.

Secara lebih sederhana nama tengah ialah selain nama depan dan nama belakang. :D

Rumus Excel yang kita gunakan untuk megambil nama tengah ini adalah:

=MID(B2;FIND(" ";Nama_Lengkap;1)+1;FIND(" ";Nama_Lengkap;1)+LEN(RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND("*";SUBSTITUTE(Nama_Lengkap;" ";"*";LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")))))))

Untuk menghindari error pada nama yang hanya terdiri dari satu kosa kata gunakan IFERROR ibarat sebelumnya:

=IFERROR(MID(Nama_Lengkap;FIND(" ";Nama_Lengkap;1)+1;FIND(" ";Nama_Lengkap;1)+LEN(RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND("*";SUBSTITUTE(Nama_Lengkap;" ";"*";LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")))))));"")

Hasilnya akan ibarat pada gambar dibawah ini:



Sebagai catatan bahawa rumus pengambilan atau pemisahan nama tengah diatas akan menghasilkan teks kosong ("") untuk nama lengkap yang hasny terdiri dari satu atau dua kosa kata.

Jika anda perhatikan lebih teliti sesungguhnya rumus-rumus diatas juga mengikut sertakan rumus-rumus untuk pemisahan nama depan dan belakang yang sudah kita bahas di bagaian atas.

Itulah salah satu alasan saya kenapa nama tengah ini saya bahas sehabis membahas nama depan dan nama belakang terlebih dahulu. Sehingga pada prakteknya anda tidak harus memakai rumus diatas, namun sanggup anda sederhanakan lagi.

Caranya bagaimana? Silahkan uji kreatifitas anda. Sebagai embel-embel silahakan download file latihan dibawah ini:

Dropbox
GDrive

*Jika link mati / tidak sanggup diakses silahkan lapor via kontak yang tersedia

FacebookTwitterWhatsapp

LINK DOWNLOAD TERKUNCI.
Silahkan SHARE untuk membuka kunci!

Setelah memahami cara mengambil nama depan, tengah dan belakang, cobalah untuk menciptakan sebuah tabel gres dengan kolom nomor urut, nama lengkap. nama depan, nama tengah dan nama belakang.

Kemudian isi kolom nomor urut dengan nomor urut. Kemudian isi baris-baris pada nama lengkap dengan nama-nama terserah anda. Usahakan jumlah kata pada nama lengkap bervariasi dan cobalah gunakan rumus-rumus excel diatas untuk memisahkna nama-nama tersebut.

Semoga berhasil. :D

Location:

Share :